***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 29, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5544-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.96
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=390.2  VTO=2.39  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=2.5e10  gamma=1.0)
Rd     d1    d2    2.2m TC=4.5m,12u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=44  TBV1=5.855e-4 TBV2=5.055e-7  CJO=2.594e-9  M=1.175  VJ=8.509)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=7.748e-11  N=1.125  RS=12.04u  EG=1.09  TT=20n ikf=3.106e+2)
Rdiode  d1  21    2.386e-3 TC=2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   4.994e-10
.MODEL     DGD    D(M=1.496   cjo=4.994e-10   VJ=7.368)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    2.730e-9
.ENDS
*$
